The dream, AutoHotkey-powered foot pedal for programmers and ergonomanics

As a hobby programmer and someone who in general use the computer a lots, I'm acutely aware of my hands/arms's general well-being ever since I felt the symptoms of numbness a few years back. Often times not using the computer or typing less is not an option, and a foot pedal is a godsend so that my feet can relieve my hands' duties from time to time.


Some foot pedals out there designed (as they claim) explicitly for ergonomically-minded people are just outrageously expensive, not to mention that their drivers / software do not seem to be very flexible. So, instead of those pedals, I picked up an Infinity transcription foot pedal (INFINITY-IN-USB-1) for less than 40 bucks on eBay, and hacked my own driver for it. The Infinity pedal is designed for transcription (i.e. has Play/Rew/Fwd buttons), but it has 3 sturdy buttons and is actually a great pedal to be re-purposed.


AutoHotkey is the key (puns not intended) to getting this pedal to work exactly the way I wanted. AutoHotKey is an amazing macro / hotkey scripting tool on Windows. It's lightweight, portable, and very powerful - albeit with a slightly awkward syntax. The important backend to my foot pedal "driver" is a few extra functions for AutoHotkey to deal with input from a Human Interface Device (HID), and is due to some helpful forum poster at the AutoHotKey forum, adapted by me.

The Infinity pedal registers itself to Windows as a HID device, and presses and releases of the buttons send combinations of numbers (see code below for details). It is technically capable of distinguishing simultaneous pedal presses as well, though my foot dexterity is not so great and I never utilize this particular possibility.

My AutoHotkey script is below. To use it, download AutoHotKey from its website; grab the script at the end of this post and save it to something like footpedal.ahk, and drag the script (in Windows Explorer) to the AutoHotKey.exe icon to run it. This script is not intended to be feature complete; rather, it's a skeleton for you to build your own dream foot pedal setup. You can make executable from that script as well (see AutoHotKey's website for details), though it might be much more useful for you to adapt the code to do exactly what you want before you compile it into an executable.

How I use it? The big "Play" button is my generalized page down key. It sends page down by default, though when certain windows are in focus, it sends other keys that act more like page down in that context (for example, I get some of my daily news dosage from Google Fast Flip, and sending the "n" key on that webpage will move to the next story). The left button acts as Alt-Tab to switch windows, and the right button just simulate a left mouse click. (In the past, the left and right button served as extra Ctrl and Alt for me since I am an avid Emacs user, though I found myself using them not so often).

To avoid confusion, though, I leave out those custom code below, and the script below only opens useless message boxes about which pedal is pressed or which is up. You can easily change those MsgBox lines to make them do whatever you want (AutoHotkey permitting :)). The only functions that you need to change should be PressKey() and ReleaseKey().

Without further ado, here is the script. Feel free to adapt it to your heart's content ;)

OnMessage(0x00FF, "InputMessage")
 
RegisterHIDDevice(12, 3) ; Register Foot Pedal
 
PedalLastPress := 0
 
Return
 
ProcessPedalInput(input)
{
    global PedalLastPress
     
    ; The input are combinations of 1, 2, 4 with 00 appended to the end
    ; indicating which pedals are pressed.
    ; For example, pressing the leftmost pedal triggers input 100, middle pedal 200, etc.
    ; all three pedals presses together will trigger 700 (1 ^ 2 ^ 4 = 7)
    ; Release of pedal trigger an input indicating what pedals are still held down
     
    input := input//100
    If (input > PedalLastPress)
      PressKey((PedalLastPress & input) ^ input)
    Else
      ReleaseKey((PedalLastPress & input) ^ PedalLastPress)
     
    PedalLastPress := input
}
     
PressKey(bits)
{
    ;ToolTip Pressing %bits%
    If (bits & 1) ; left pedal
    {
  Msgbox Left pedal pressed!
    }
    Else If (bits & 4) ; right pedal
    {
     Msgbox Right pedal pressed!
    }
    Else ; center pedal
    {
  MsgBox Center pedal pressed!
    }
    }

ReleaseKey(bits)
{
    ;ToolTip Releasing %bits%
    If (bits & 1)
     MsgBox left pedal up!
    Else If (bits & 4)
     MsgBox Right pedal up!
    Else
  MsgBox Center pedal up!
    
}
 
Mem2Hex( pointer, len )
{
A_FI := A_FormatInteger
SetFormat, Integer, Hex
Loop, %len%  {
Hex := *Pointer+0
StringReplace, Hex, Hex, 0x, 0x0
StringRight Hex, Hex, 2          
hexDump := hexDump . hex
Pointer ++
}
SetFormat, Integer, %A_FI%
StringUpper, hexDump, hexDump
Return hexDump
}
 
; Keyboards are always Usage 6, Usage Page 1, Mice are Usage 2, Usage Page 1,
; HID devices specify their top level collection in the info block  
RegisterHIDDevice(UsagePage,Usage)
{
; local RawDevice,HWND
RIDEV_INPUTSINK := 0x00000100
DetectHiddenWindows, on
HWND := WinExist("ahk_class AutoHotkey ahk_pid " DllCall("GetCurrentProcessId"))
DetectHiddenWindows, off
 
VarSetCapacity(RawDevice, 12)
NumPut(UsagePage, RawDevice, 0, "UShort")
NumPut(Usage, RawDevice, 2, "UShort")    
NumPut(RIDEV_INPUTSINK, RawDevice, 4)
NumPut(HWND, RawDevice, 8)
 
Res := DllCall("RegisterRawInputDevices", "UInt", &RawDevice, UInt, 1, UInt, 12)
if (Res = 0)
MsgBox, Failed to register for HID Device
}       
InputMessage(wParam, lParam, msg, hwnd)
{
RID_INPUT   := 0x10000003
RIM_TYPEHID := 2
SizeofRidDeviceInfo := 32
RIDI_DEVICEINFO := 0x2000000b
 
 
DllCall("GetRawInputData", UInt, lParam, UInt, RID_INPUT, UInt, 0, "UInt *", Size, UInt, 16)
VarSetCapacity(Buffer, Size)
DllCall("GetRawInputData", UInt, lParam, UInt, RID_INPUT, UInt, &Buffer, "UInt *", Size, UInt, 16)
 
Type := NumGet(Buffer, 0 * 4)
Size := NumGet(Buffer, 1 * 4)
Handle := NumGet(Buffer, 2 * 4)
 
VarSetCapacity(Info, SizeofRidDeviceInfo)  
NumPut(SizeofRidDeviceInfo, Info, 0)
Length := SizeofRidDeviceInfo
 
DllCall("GetRawInputDeviceInfo", UInt, Handle, UInt, RIDI_DEVICEINFO, UInt, &Info, "UInt *", SizeofRidDeviceInfo)
 
VenderID := NumGet(Info, 4 * 2)
Product := NumGet(Info, 4 * 3)
 
;   tooltip %VenderID% %Product%
 
 
if (Type = RIM_TYPEHID)
{
SizeHid := NumGet(Buffer, (16 + 0))
InputCount := NumGet(Buffer, (16 + 4))
Loop %InputCount% {
Addr := &Buffer + 24 + ((A_Index - 1) * SizeHid)
BAddr := &Buffer
Input := Mem2Hex(Addr, SizeHid)
If (VenderID = 1523 && Product = 255) ; need special function to process foot pedal input
ProcessPedalInput(Input)
Else If (IsLabel(Input))
{
Gosub, %Input%
}
 
}
}
}